Bu derste;

• UILoader'ları Kullanmak,
• ActionScript İle UILoader Oluşturmak,
• UIScrollBar'ları Kullanmak,
• ActionScript İle UIScrollBar Oluşturmak

konularına değinilmiştir.

• UILoader'ları Kullanmak: UILoader bileşeni, SWF, JPEG, progressive JPEG, PNG, ve GIF dosyalarını gösteren bir taşıyıcıdır. Uzaktaki bir yerden yukarıdaki içeriklerden biri form içine UILoader bileşeniyle alınabilmektedir. UILoader bileşeni, ayrıca uygulamaların içine resim yüklemek içinde kullanılabilmektedir. İçerik yüklemek için load() metodu kullanılırken, percentLoaded özelliği ile de ne kadar miktarda içerik yüklendiği öğrenilebilir. Complete olayı ise, içerik yüklemenin bittiği zamanı kontrol eder. UILoader bileşeninin içeriğinin büyüklüğü ve oranı değiştirilebilmektedir. İlk anda varsayılan olarak içeriklerin oranı UILoader bileşeni ile uygunluk göstermektedir.

Bir UILoader bileşeninin Property özelliklerindeki Parametre sekmesinden alanları "autoLoad", "maintainAspectRatio", "source" ve "scaleContent" kontrol edilebilir.

ActionScript İle UILoader Oluşturmak:

UILoader bileşeni Components panelinden çift tıklanarak kütüphaneye aktarılır. Actionscript paneli açılır ve aşağıdaki kod satırlarını yazılarak uygulama test edilir.

import fl.containers.UILoader;    
// UILoder sınıfı uygulamaya dahil edildi
var yukleme:UILoader = new UILoader();  
 // yukleme adlı UILoder nesnesi oluşturuldu
yukleme.source = "http://www.unicef.org/turkey/sy3/img/is3.jpg";
// yukleme adlı UILoder nesnesine internet adresinden jpg resmini yüklemesi söylendi
yukleme.scaleContent = false;
// yukleme adlı UILoder nesnesinin boyutunun  yüklenen
// içerik boyutu ile aynı olmaması sağlandı
yukleme.addEventListener(Event.COMPLETE, yuklemeBitti);
// yukleme adlı UILoder nesnesine olay dinleyici bağlandı, 
// yükleme tamamlandığında yuklemeBitti fonksiyonu çağrıldı
function yuklemeBitti(event:Event)
{
trace("Yüklenen Byte Miktarı: " + yukleme.bytesLoaded);
 // yukleme adlı UILoder nesnesine yüklenen resmin boyutu öğrenildi
} 
addChild(yukleme); 
//yukleme adlı UILoder nesnesi sahneye taşındı

• UIScrollBar'ları Kullanmak:

UIScrollBar bileşeni, metin alanlarına yatay veya dikey scroll eklemek için kullanılan bir bileşendir. Bir UIScrollBar bileşeninin Property özelliklerindeki Parametre sekmesinden "direction" ve "scrollTargetName" alanları kontrol edilebilir.

ActionScript İle UIScrollBar Oluşturmak:

UIScrollBar bileşeni Components panelinden çift tıklanarak kütüphaneye aktarılır. Actionscript paneli açılır ve aşağıdaki kod satırlarını yazılarak uygulama test edilir.

import flash.net.URLLoader;
import fl.controls.UIScrollBar;
import flash.events.Event;
// URLLoader, UIScrollBar, Event sınıflarıı uygulamaya dahil edildi
var metinAlani:TextField = new TextField(); 
// TextField nesnesi oluşturuldu
metinAlani.border = true;
metinAlani.width = 200;
metinAlani.height = 40;
metinAlani.x = 200;
metinAlani.y = 150;
// TextField nesnesinin sınır,genişlik,yükseklik, x ve y konumları ayarlandı 
var kaydirmaCubugu:UIScrollBar = new UIScrollBar();
// kaydırmaCubugu adlı UlScrollBar nesnesi oluşturuldu
kaydirmaCubugu.direction = "horizontal";
// kaydırmaCubugu adlı UlScrollBar nesnesinin 
//scroll yönü yatay olarak ayarlandı
kaydirmaCubugu.setSize(metinAlani.width, metinAlani.height);
// kaydırmaCubugu adlı UlScrollBar nesnesinin boyutu
// metinAlanı nesnesinin boyutu olarak ayarlandı

kaydirmaCubugu.move(metinAlani.x, metinAlani.height + metinAlani.y);
// kaydırmaCubugu adlı UlScrollBar nesnesinin boyutu metinAlanı
// nesnesinin konumu olarak ayarlandı

var yukleme:URLLoader = new URLLoader();
var request:URLRequest = new URLRequest("http://www.deneme.com/deneme.txt");
yukleme.load(request);
// yukleme adlı URLLoader nesnesi oluşturularak 
// internetten txt dosyası yüklendi
yukleme.addEventListener(Event.COMPLETE, yuklemeBitti);
//  yukleme adlı URLLoader nesnesine olay dinleyici bağlanarak
// yükleme tamamlandığında yuklemeBitti fonksiyonu çağrıldı.
function yuklemeBitti(event:Event)
{
metinAlani.text = yukleme.data;
// metinAlanının text özelliğine,  yukleme adlı 
//URLLoder nesnesindeki veri aktarıldı.

kaydirmaCubugu.scrollTarget = metinAlani;
// kaydirmaCubugu adlı UIScrollBar nesnesi, 
//metinAlani adlı TextField nesnesine bağlandı.

}
addChild(metinAlani);
addChild(kaydirmaCubugu);
// metinAlanı ve kaydirmaCubugu adlı nesneler sahneye taşındı

Yazan: Muttalip TULGAR

"ActionScript 3.0: Bileşenler (Components) X" dersinde görüşmek üzere…