Bu derste;

• TextInput'ları Kullanmak,
• ActionScript İle TextInput Oluşturmak,
• TileList'leri Kullanmak,
• ActionScript İle TileList Oluşturmak,

konularına değinilmiştir.

• TextInput'ları Kullanmak:

TextInput bileşeni, tek satırlık bir metin bileşeni olup ActionScript TextField nesnesi için bir barınak niteliğindedir. Eğer çok satırlı bir metin oluşturulacaksa TextArea bileşeni tercih edilmelidir. TextInput bileşeni özellikle formlarda password alanlarında kullanılmaktadır. TextInput örneğinde görülen metnin biçimi, setStyle() metodu kullanılarak textFormat sitili ile ayarlanabilir. Ayrıca htmlText özelliği ile TextInput örneği HTML biçiminde kullanılabilir. TextInput bileşenini klavyden kontrol etmek için "Shift+Tab", "Tab" ve yön tuşları kullanılmaktadır.

Bir TextInput bileşeninin Property özelliklerindeki Parametre sekmesinden alanları "editable", "displayAsPassword", "maxChars", "restrict" ve "text" kontrol edilebilir.

ActionScript İle TextInput Oluşturmak:

TextInput ve Label bileşenleri Components panelinden çift tıklanarak kütüphaneye aktarılır. Actionscript paneli açılır ve aşağıdaki kod satırlarını yazılarak uygulama test edilir.

import fl.controls.Label;
import fl.controls.TextInput;
// Label veTextInput  sınıfları uygulamaya dahil edildi
var etiket:Label = new Label();
var aTi:TextInput = new TextInput();
var tf:TextFormat = new TextFormat();
// Label veTextInput ve TextFormat  nesneleri oluşturuldu
tf.font = "Arial";
tf.color = 0x0000CC;
tf.size = 18;
// tf adlı TextFormat nesnesinin yazı tipi, 
//yazı rengi ve yazı boyutu özellikleri ayarlandı
etiket.text = "Ad: "
etiket.setSize(50, 25);
etiket.move(100,100);
etiket.setStyle("textFormat", tf);
// etiket  adlı Label  nesnesinin metin, boyut,konum 
//özellikleri ile  metnine uygulanacak sitil belirlendi

aTi.restrict = "A-Z .a-z"; 
// aTi adlı TextInput  nesnesinin metin özelliği
// harflerle sınırlandı (Rakam yazılamaz)
aTi.move(160, 100);  // aTi adlı TextInput  nesnesinin konumu ayarlandı
aTi.maxChars=8;   
// aTi adlı TextInput  nesnesinin metin özelliği 8 karakterle  sınırlandı 
aTi.setSize(200, 25);   // aTi adlı TextInput  nesnesinin boyutu ayarlandı
aTi.setStyle("textFormat", tf); 
//aTi adlı TextInput  nesnesinin metnine uygulanacak sitil belirlendi
addChild(etiket);  // etiket  adlı Label  nesnesi sahneye taşındı
addChild(aTi);     // aTi adlı TextInput  nesnesi sahneye taşındı

• TileList'leri Kullanmak:

TileList bileşeni, farklı yapıdaki verileri satır ve sütünlerden oluşan bir liste içinde barındıran veri gösterme bileşenidir. TileList bileşeni özellikle fotoğraf albümlerinin önizlemesinde kullanılan bir bileşendir. Data provider ile aktarın veriler, TileList bileşeni içinde label (etiket) özelliği ve source (kaynak) özelliği ile bulunmaktadır. Label özelliği, veri tipini belirten bir etiket iken, source verinin nereden geldiğini belirten bir özelliktir. Label, tek bir satır olarak her zaman hücrenin en altında yer almaktadır. Öte yandan TileList bileşeni sadece tek bir yönde scroll özelliğine sahiptir. Ayrıca bir Array nesnesi oluşturularak anabilgisayardan veriler çekilebilir. TileList bileşenine addItem() ve removeItem() metotları ile de veri ekleme ve çıkarma yapılabilir. TileList bileşenini klavyden kontrol etmek için "Home", "End", "Ctrl" ve yön tuşları kullanılmaktadır.

Bir TileList bileşeninin Property özelliklerindeki Parametre sekmesinden alanları "allowMultipleSelection", "columnCount", "columnWidth", "dataProvider", "direction", "horizontalScrollLineSize", "horizontalScrollPageSize", "labels", "rowCount", "rowHeight", "ScrollPolicy", "verticalScrollLineSize", "verticalScrollPageSize" kontrol edilebilir.

ActionScript İle TileList Oluşturmak:

ColorPicker, ComboBox, NumericStepper, CheckBox, TileList bileşenleri Components panelinden çift tıklanarak kütüphaneye aktarılır. Actionscript paneli açılır ve aşağıdaki kod satırlarını yazılarak uygulama test edilir.

import fl.controls.CheckBox;
import fl.controls.ColorPicker;
import fl.controls.ComboBox;
import fl.controls.NumericStepper;
import fl.controls.TileList;
import fl.data.DataProvider;
// CheckBox, ColorPicker, ComboBox, NumericStepper, TileList ve 
//DataProvider sınıfları uygulamaya dahil edildi
var aCp:ColorPicker = new ColorPicker();
var aCb:ComboBox = new ComboBox();
var aNs:NumericStepper = new NumericStepper();
var aCh:CheckBox = new CheckBox();
var aTl:TileList = new TileList();
// ColorPicker, ComboBox, NumericStepper, CheckBox ve 
// TileList nesneleri oluşturuldu
var dp:Array = [
{label:"ColorPicker", source:aCp},
{label:"ComboBox", source:aCb},
{label:"NumericStepper", source:aNs},
{label:"CheckBox", source:aCh},
];
// dp adlı Array nesnesi oluşturularak bileşenlerin 
//etiket ve kaynak özellikleri tutuldu
aTl.dataProvider = new DataProvider(dp);
// aTI adlı TileList nesnesine dataProvider nesnesi ile 
//dp adlı Array'deki  veriler bağlandı
aTl.columnWidth = 110;
aTl.rowHeight = 100;
aTl.setSize(280,130);
aTl.move(150, 150);
aTl.setStyle("contentPadding", 5);
// aTI adlı TileList nesnesinin sütün genişliği, satır yüksekliği,
// boyutu ve konumu ve sitili ayarlandı
aTl.sortItemsOn("label");   
// aTI adlı TileList nesnesindeki
// veriler label özelliğine göre sıralandı
addChild(aTl);    
// aTI adlı TileList nesnesi sahneye taşındı

Programın Ekran Çıktısı

Yazan: Muttalip TULGAR

"ActionScript 3.0: Bileşenler (Components) IX" dersinde görüşmek üzere…