Flash ile birçok çalışmamızda Array sınıfını kullanıyoruz. Bazen ürünlerimizi listeliyoruz, bazen görsel objelerimizi depoluyoruz.

AS3 ile gelen displayList bile bir nevi Array. Peki CS4 ile gelen Vector sınıfına ne demeli? Daha yazımını görünce bile şaşırtıyor.

Örnek:

var vector:Vector.<int> = new Vector.<int>;

Alıştığımız bir yazı biçimi değil. Ama bu satırdan anlıyoruzki bu dizinin elemanlarının türü sadece int olabilir.

Vector ve Array Farkı: Vector ara elemanları tanımlanmamışsa null değeri alıyor.

Örnek:

var a:Array = new Array();
a[0] = "eleman";
a[6] = "eleman";
trace(a)

Bu kodu test ederseniz ara elemanlar direk boş gözükecektir.Aynı örneği Vector sınıfında denerseniz eğer:

var v:Vector.<String> = new Vector.<String>();
v[0] = "eleman";
v[6] = "eleman";
trace(v)

Ara elemanların null değeri aldığını görebilirsiniz.Dahası da var. Vector sınıfında aynı Array sınıfındaki gibi uzunluk değerini başta girebiliyorsunuz.

Örneğin:

var v:Vector.<String> = new Vector.<String>(4); 
v.push("a");  
v.push("b");
trace(v)

Bu kodu çalıştırdığınızda ilk 4 eleman null olacaktır ve push ile atadığımız veriler sona eklenecektir. Ama şunu denerseniz:

var v:Vector.<String> = new Vector.<String>(4); 

v[0]="h";
v.push("a");  
v.push("b");
trace(v)

İlk eleman h olarak gözükecektir.

Vector sınıfını Array’dan ayıran bir başka özellik ise uzunluğu koruma özelliğidir. Örneğin:

var v:Vector.<String> = new Vector.<String>(4,true); 
v[0]="a";
trace(v)

Bu kodu denediğinizde ilk eleman a olarak gözükecek. Şimdi şu kodu test edin:

var v:Vector.<String> = new Vector.<String>(4,true); 
v.push("a");
trace(v)

Normalde bu kod uzunluğu değiştiriyor. Ama biz izin vermediğimiz için hata vericektir:

RangeError: Error #1126: Sabit bir vektörün uzunluğu değiştirilemez.
    at Vector$object/http://adobe.com/AS3/2006/builtin::push()
    at Untitled_fla::MainTimeline/frame1()

Vector sınıfını da tanıyınca şimdi gelelim asıl Array ile asıl karşılaştırmasına.

Performans Farkı Yazılım biçiminden kurallarına kadar farklılık gösterdiğine göre performans farkı da olmalı ki var zaten.

Örneğin şu kodu çalıştıralım:

var vector:Vector.<int> = new Vector.<int>;
var array:Array = new Array();
var sTime:Number = 0;
function arrayTest() {
    for( var i:int=0; i<5000000; i++) {
        array.push(i);
    }
}
function vectorTest() {
    for( var i:int=0; i<5000000; i++) {
        vector.push(i);
    }
}
sTime = getTimer();
arrayTest();
trace("Array Test: "+ String( getTimer() - sTime));
sTime=getTimer();
vectorTest();
trace("Vector Test: "+ String( getTimer() - sTime));

Bu kodu çalıştırdığınızda göreceksinizki dizilerin işleme süresi vectorleri işleme süresinden fazla. Eğer tek tip bir dizi oluşturacaksanız Vector kullanmanızda fayda var.

Kolay gelsin…