Merhaba, aşağıdaki kod, bir resmi nasıl boyutlandıracağınız konusunda size fikir verecektir. Bu kod, flash uygulamasının ilk frame’inde olmalıdır.

// Kütüphanemizde, attachMovie yöntemi ile sahneye çağıracağımız 2
//adet film klibimiz olmalıdır(boyutlandir ve buton)
// her iki film klibimizin de linkage seçeneği aktif edilmiş olmalıdır
// buton film klibimizin identifier'ı 'buton' olmalıdır ve basit bir buton görünümüne
//sahip olmalıdır.
//boyutlandir film klibimizin identifier'ı 'boyutlandir' olmalıdır ve boş bir film klibi
// biçimde düzenlenmelidir.
//buton film klibi ile resimleri çağıracağız, boyutlandir film klibi
//ile çağırdığımız resimleri yeniden boyutlandıracağız.
//burada önemli olan, resimlerin en-boy oranlarını koruyarak (proportions)
// boyutlandırma işlemini yapabilmektir.
//---kod başlangıcı--//
//attachmovie işleminin her resimde bir üst derinlik
//seviyesine ulaşması için derinlik değişkeni atayalım
derinlik = 0;
// boyutlandir film klibinin bir resme uygulayacağı
// maksimum genişlik değerini atayalım
maxWidth = 400;
// boyutlandir film klibinin bir resme uygulayacağı
// maksimum yükseklik değerini  atayalım
maxHeight = 300;
//yüklenecek olan resimleri ya da swf dosyalarını bir dizi içerisine 
//atayalım. Bu isimler, farklı biçimlerde de olabilir.
//önemli olan, dosya uzantılarını yazmadan yalnızca isimleri dizi içerisinde bildirmektir.
//Eğer bu örnekteki gibi .jpg uzantılı dosyalar değil de
//.swf uzantılı dosyalar yükleyecekseniz *//jpg.loadMovie(resimler[Number(this._name.substr(3))]+'.jpg');//*
//kod satırının sonundaki '.jpg' ifadesini .swf biçiminde düzenlemelisiniz.
resimler = ['1', '2', '3'];
//boyutlandir film klibimizi sahneye çağıralım
this.attachMovie('boyutlandir', 'boyutlandir', derinlik++);
//boyutlandir film klibinin yeniden boyutlandırdığı
//resimleri içerisine yükleyeceğimiz jpgisimli boş  film klibini
//  ve x ve y değerlerini deklare edelim 
this.createEmptyMovieClip('jpg', derinlik++);
jpg._x = jpg._y=250;
// Buton tarafından çağrılacak olan resim yükleme fonksiyonunu
//deklare edelim
resimYukle = function () {
    //butonumuz resim yükle fonksiyonunu tetiklediğinde
    //jpg film klibine resimler dizisinden resim adını
    //seçelim ve .jpg uzantısı ile birleştirerek 
    //yükleyelim
    jpg.loadMovie(resimler[Number(this._name.substr(3))]+'.jpg');
    // boyutlandir film klibine bir onenterframe fonsiyonu atayalım
    //ve yükleme işleminin gerçekleşip gerçekleşmediğini
    //kontrol edelim
    boyutlandir.onEnterFrame = function() {
        if (jpg.getBytesTotal()>0 && jpg.getBytesLoaded() == jpg.getBytesTotal()) {
            //yükleme gerçekleşmişse, resmi içeren jpg film klibini
            //görünür kılalım
            jpg._visible = true;
            //Eğer yüklenen resim, deklare ettiğimiz maksimum yükseklik ve genişlik
            //değerlerinden büyük ise
            //yeniden boyutlandıralım
            if (jpg._width>maxWidth || jpg._height>maxHeight) {
                jpg._xscale = jpg._yscale=Math.min(100*maxWidth/jpg._width, 100*maxHeight/jpg._height);
            }
            // boyutlandir film klibinin toplam genişliğini       
            //butonlarımızı da hesaba katarak belirtelim
            // ve yeniden boyutlandırma işlemini başlatalım
            boyutlandirWidth = jpg._width+btns._width+10;
            deltaX = Math.round((boyutlandirWidth-boyutlandir._width));
            boyutlandirWidth = deltaX+boyutlandir._width;
            deltaY = Math.round((jpg._height+20-boyutlandir._height));
            jpg.onEnterFrame = function() {
                if ((boyutlandir._width<boyutlandirWidth && deltaX>0) || (boyutlandir._width>boyutlandirWidth && deltaX<0)) {
                    boyutlandir._width += deltaX;
                    boyutlandir._height += deltaY;
                    btns._x = 10;
                }
            };
        }
    };
};
// yükleyeceğimiz resimler, birden fazla olduğuna göre
//sahnedeki butonumuzu da resim sayısına göre çoğaltmalıyız
//bunun için bir boş film klibi yaratalım
// ve buton film klibimizi ve varsa diğer örneklerini
//bu film klibinin içine alalım
this.createEmptyMovieClip('btns', derinlik++);
btns._x = btns._y=10;
for (var i = 0; i<resimler.length; i++) {
    btns.attachMovie('buton', 'btn'+i, i, {_y:20*i, image:resimler[i], onRelease:resimYukle});
}

uygulamayı test etmek için, kodda yer alan dizideki resim isimlerine sahip büyük boyutlarda resimler oluşturun ve yükleyin. Resimlerin yeniden boyutlandırıldığını ve en-boy oranlarının sabit kaldığını görmelisiniz.

iyi dileklerimle.

Güzel Paylaşım Teşşekürler. Emeğinize Sağlık

if(resmi_yuklediginiz_mc._width > istenilen_genislik){
resmi_yuklediginiz_mc._width = istenilen_genislik;
resmi_yuklediginiz_mc._yscale = resmi_yuklediginiz_mc._xscale;
}
if(resmi_yuklediginiz_mc._height > istenilen_yukseklik){
resmi_yuklediginiz_mc._height = istenilen_yukseklik;
resmi_yuklediginiz_mc._xscale = resmi_yuklediginiz_mc._yscale;
}

(bu koda birde resim yüklendiğince çalışmasını belirten bir tetikleyici koymak gerekir ama boyutlandırma işlemi için gerekli kod bu kadardır)

tabiki seviyeniz daha ilerideyse uygulanması gereken diğer kurallara uymanız gerekecektir.